Finding the zone of a letter in a note by Visualbasic

I'll look into it as I have time. Unfortunately, my current schedule does not allow much time for writing journal code.

For a preview, here is how you can create the notes in interactive NX:
Find a section view and the corresponding parent view.
Start the note command, in the 'symbols' section of the dialog choose "insert sheet zone". Choose "sheet number" and select the parent view. Insert sheet zone again, pick "zone reference" and again select the parent view. Place the note under the section view label and associate the note to the view (or view label if you prefer).
Follow a similar process to note the section view location and associate the note to the parent view.

The journal code will simply automate the process of finding the section views and creating the notes.

If the zone note shows "??", that indicates that the zone option is not set up correctly and NX can't find the zone information.

The code below is a crude implementation of the process that I described. The journal will create a note associated to the view and place it below the view. If the view has multiple sections created from it, the notes will overlap; this is something that would need to be fixed for production use.

The code below was written/tested on NX 9 native. The NX borders & zones tool needs to be used to define the borders; it won't work if the zones are manually created in your drawing template file.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module Module1

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()
Dim workPart As Part = theSession.Parts.Work

Dim lw As ListingWindow = theSession.ListingWindow

Sub Main()

If IsNothing(theSession.Parts.BaseWork) Then
'active part required
Return
End If

lw.Open()

Dim allZonesDefined As Boolean = True
For Each dwgSheet As Drawings.DrawingSheet In workPart.DrawingSheets
Dim dwgBorders As Drawings.BordersAndZones
dwgBorders = dwgSheet.BordersAndZones
If IsNothing(dwgBorders) Then
'no zones defined
lw.WriteLine("no zones defined for drawingsheet: " & dwgSheet.Name)
allZonesDefined = False
End If
Next

If Not allZonesDefined Then
Return
End If

Const undoMarkName As String = "label section view zone"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

For Each temp As Drawings.DraftingView In workPart.DraftingViews

If TypeOf (temp) Is Drawings.SectionView Then

Dim parentView As Drawings.DraftingView
parentView = SectionViewParent(temp)

If IsNothing(parentView) Then
Continue For
End If

Dim theSheet As Drawings.DrawingSheet
theSheet = AskDrawingSheet(parentView)
theSheet.Open()

AddNoteRelativeToView(temp, parentView)

theSheet = AskDrawingSheet(temp)
theSheet.Open()
AddNoteRelativeToView(parentView, temp)

End If

Next

lw.Close()

End Sub

Function SectionViewParent(ByVal sxView As Drawings.SectionView) As Drawings.DraftingView

Dim sectionLineTag As Tag = Tag.Null
theUfSession.Draw.AskSxlineOfSxview(sxView.Tag, sectionLineTag)

Dim sectionLineType As UFDraw.SxlineType
theUfSession.Draw.AskSxlineType(sectionLineTag, sectionLineType)

Dim stepDir(2) As Double
Dim arrowDir(2) As Double
Dim parentViewTag As Tag = Tag.Null
Dim parentView As Drawings.DraftingView
Dim numSxViews As Integer
Dim sxViewTags() As Tag = Nothing
Dim numSegments As Integer
Dim segmentTags() As Tag = Nothing
Dim status As UFDraw.SxlineStatus
Dim rotationPtObj As UFDrf.Object = Nothing
Dim numLeg1Segments As Integer
Dim cutPlaneLeg As UFDraw.SxlineLeg

Select Case sectionLineType
Case Is = UFDraw.SxlineType.SimpleSxline
theUfSession.Draw.AskSimpleSxline(sectionLineTag, stepDir, arrowDir, parentViewTag, numSxViews, sxViewTags, numSegments, segmentTags, status)

Case Is = UFDraw.SxlineType.SteppedSxline
theUfSession.Draw.AskSteppedSxline(sectionLineTag, stepDir, arrowDir, parentViewTag, numSxViews, sxViewTags, numSegments, segmentTags, status)

Case Is = UFDraw.SxlineType.RevolvedSxline
theUfSession.Draw.AskRevolvedSxline(sectionLineTag, stepDir, arrowDir, parentViewTag, rotationPtObj, numSxViews, sxViewTags, numSegments, numLeg1Segments, cutPlaneLeg, segmentTags, status)

Case Is = UFDraw.SxlineType.HalfSxline
theUfSession.Draw.AskHalfSxline(sectionLineTag, stepDir, arrowDir, parentViewTag, numSxViews, sxViewTags, numSegments, segmentTags, status)

Case Is = UFDraw.SxlineType.UnfoldedSxline
theUfSession.Draw.AskUnfoldedSxline(sectionLineTag, stepDir, arrowDir, parentViewTag, numSxViews, sxViewTags, numSegments, segmentTags, status)

Case Is = UFDraw.SxlineType.FoldedSxline

Case Is = UFDraw.SxlineType.Breakline
'the view with the break is the section view itself

End Select

If parentViewTag = Tag.Null Then
Return Nothing
End If

parentView = Utilities.NXObjectManager.Get(parentViewTag)
Return parentView

End Function

Sub AddNoteRelativeToView(ByVal viewZoneInfo As Drawings.DraftingView, ByVal noteView As Drawings.DraftingView)

Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Invisible, "Note")

Dim nullAnnotations_SimpleDraftingAid As Annotations.SimpleDraftingAid = Nothing

Dim draftingNoteBuilder1 As Annotations.DraftingNoteBuilder
draftingNoteBuilder1 = workPart.Annotations.CreateDraftingNoteBuilder(nullAnnotations_SimpleDraftingAid)

draftingNoteBuilder1.Origin.Anchor = Annotations.OriginBuilder.AlignmentPosition.MidCenter

draftingNoteBuilder1.Origin.Plane.PlaneMethod = Annotations.PlaneBuilder.PlaneMethodType.XyPlane

Dim associativeText1 As Annotations.AssociativeText
associativeText1 = workPart.Annotations.CreateAssociativeText()

Dim text4 As String
text4 = associativeText1.GetObjectPropertyText(viewZoneInfo, Annotations.AssociativeText.PropertyType.DrawingSheetName)

associativeText1.Dispose()

Dim associativeText2 As Annotations.AssociativeText
associativeText2 = workPart.Annotations.CreateAssociativeText()

Dim text6 As String
text6 = associativeText2.GetObjectPropertyText(viewZoneInfo, Annotations.AssociativeText.PropertyType.DrawingSheetZone)

associativeText2.Dispose()

Dim text7(0) As String
text7(0) = "SEE " & text4 & " " & text6

draftingNoteBuilder1.Text.TextBlock.SetText(text7)

Dim assocOrigin1 As Annotations.Annotation.AssociativeOriginData
assocOrigin1.OriginType = Annotations.AssociativeOriginType.RelativeToView
assocOrigin1.View = noteView
Dim nullView As View = Nothing

draftingNoteBuilder1.Origin.SetAssociativeOrigin(assocOrigin1)

Dim viewSize(3) As Double
'retrieve the size of the view
theUfSession.Draw.AskViewBorders(noteView.Tag, viewSize)
Dim viewLength As Double = viewSize(2) - viewSize(0)
Dim viewHeight As Double = viewSize(3) - viewSize(1)

'midpoint of view location (X value)
Dim viewX As Double = viewLength / 2 + viewSize(0)

Dim point1 As Point3d = New Point3d(viewX, viewSize(1), 0.0)
draftingNoteBuilder1.Origin.Origin.SetValue(Nothing, nullView, point1)

draftingNoteBuilder1.Origin.SetInferRelativeToGeometry(True)

Dim nXObject3 As NXObject
nXObject3 = draftingNoteBuilder1.Commit()

draftingNoteBuilder1.Destroy()

End Sub

' This function will work for:
' an object which "Resides on drawing" or is "View Dependent In" a DraftingView
' a DraftingView
' a DrawingSheet.View
' Returns Nothing for all other (ie. model mode) objects
Function AskDrawingSheet(ByVal theObject As TaggedObject) As Drawings.DrawingSheet

Dim theView As View = TryCast(theObject, View)
If Not theView Is Nothing Then
Dim sheetTag As Tag = Nothing
Try
theUFSession.Draw.AskDrawingOfView(theView.Tag, sheetTag)
Return Utilities.NXObjectManager.Get(sheetTag) ' the drawing it is on
Catch ex As NXException
Return Nothing ' it is a model view
End Try
End If

Dim viewName As String = Nothing
Dim status As Integer = Nothing
Try
theUFSession.View.AskViewDependentStatus(theObject.Tag, status, viewName)
Catch ex As NXException
Return Nothing
End Try
If status = 0 Then Return Nothing ' it is a model mode object

Dim viewTag As Tag = Nothing
theUFSession.View.AskTagOfViewName(viewName, viewTag)
Dim viewType As Integer = Nothing
Dim viewSubtype As Integer = Nothing
theUFSession.View.AskType(viewTag, viewType, viewSubtype)
If viewType = 0 Then Return Nothing ' it is view dependent in a modeling view

Dim drawingTag As Tag = Nothing
theUFSession.Draw.AskDrawingOfView(viewTag, drawingTag)
Return Utilities.NXObjectManager.Get(drawingTag) ' the drawing it is on!

End Function

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module

It sounds like you are on the right track. Make sure all the entries contain valid numbers and OK the dialog when done. You will know when it worked because it will draw the border and zone information around the edges of the sheet.

There are multiple strategies that one could employ to fix the overlapping problem of the previously posted code. I'll leave it to you to implement the version that meets your needs. My intention was to show how to create and add the notes to the views. You will notice that the notes placed by the journal are associative to the view; when a view moves, the note moves with it and the zone information updates accordingly.

Some examples can be found in the NX install directory:
{NX install dir}\UGOPEN\Sample\NXOpenApplications

Of course some examples and explanation can also be found on this site.