Report Missing Parts List Balloons

'NXJournaling.com
'January 20, 2015
'
'NX 8.5
'
'Journal to report which items in a parts list do not have corresponding balloon callouts.
'Inspired by and based on the GTAC sample "report_missing_balloons_of_parts_lists" (nxapi_5333)
'by Frank Berger.
'The GTAC sample will only work with NX 9 or higher; this journal will work with NX 8.5,
'and possibly with older versions back to NX 5.
 
'Similar to _v2, but this version uses a simple list to hold the autoballoon callout numbers
'instead of a dictionary. I thought there might be a performance improvement by using a list
'rather than a dictionary. Testing on a small assembly (~120 unique parts) shows very little,
'if any difference.
 
'February 22, 2016
'  Update to ignore potential "phantom" parts list returned by Plist.AskTags
 
Option Strict Off
Imports System
Imports System.Collections.Generic
Imports NXOpen
Imports NXOpen.UF
 
Module report_missing_balloons_v3
 
    Dim theSession As Session = Session.GetSession()
    Dim theUfSession As UFSession = UFSession.GetUFSession()
 
    Dim lw As ListingWindow = theSession.ListingWindow
 
    Sub Main()
 
        If IsNothing(theSession.Parts.Work) Then
            'active part required
            Return
        End If
 
        Dim workPart As Part = theSession.Parts.Work
        lw.Open()
 
        Dim partListTags() As Tag = Nothing
        Dim numPartLists As Integer = 0
        theUfSession.Plist.AskTags(partListTags, numPartLists)
 
        'test for a dummy parts list
        '.AskTags sometimes returns a tag even on a blank part that contains no parts list
        'PR 7643749
        'lw.WriteLine("number of parts lists: " & numPartLists.ToString)
        If numPartLists > 0 Then
            For i As Integer = 0 To partListTags.Length - 1
                Dim prtList As DisplayableObject = Utilities.NXObjectManager.Get(partListTags(i))
                'lw.WriteLine("parts list layer: " & prtList.Layer.ToString)
                If prtList.Layer = 0 Then
                    numPartLists -= 1
                End If
            Next
        End If
 
        If numPartLists <= 0 Then
            lw.WriteLine("No parts list found in the work part")
            Return
        End If
 
        If numPartLists > 1 Then
            lw.WriteLine("ERROR: Cannot evaluate AutoBalloons with multiple parts lists.")
            lw.WriteLine("Check environment variable UGII_UPDATE_ALL_ID_SYMBOLS_WITH_PLIST")
            Return
        End If
 
        theUfSession.Plist.UpdateAllPlists()
 
        Dim numRows As Integer
        theUfSession.Tabnot.AskNmRows(partListTags(0), numRows)
        'lw.WriteLine("number of rows: " & numRows.ToString)
 
        Dim plistPrefs As UFPlist.Prefs = Nothing
        theUfSession.Plist.AskPrefs(partListTags(0), plistPrefs)
        'lw.WriteLine("symbol type: " & plistPrefs.symbol_type.ToString)
        'lw.WriteLine("main symbol text: " & plistPrefs.main_symbol_text)
 
        Dim colCallout As Tag = PartListCalloutColumn(partListTags(0))
        'lw.WriteLine("callout column tag: " & colCallout.ToString)
        If colCallout = Tag.Null Then
            lw.WriteLine("parts list callout column not found")
            Return
        End If
 
        Dim plBalloonList As New List(Of String)
        CollectPartsListBalloons(plBalloonList, plistPrefs.symbol_type)
 
        Dim missingBalloons As New List(Of String)
 
        Dim startTime As DateTime = Now
 
        'loop through rows of the parts list, look for corresponding autoballoon callout
        For i As Integer = 0 To numRows - 1
 
            Dim rowTag As Tag
            theUfSession.Tabnot.AskNthRow(partListTags(0), i, rowTag)
 
            Dim cellTag As Tag
            theUfSession.Tabnot.AskCellAtRowCol(rowTag, colCallout, cellTag)
 
            Dim calloutEvText As String = ""
            theUfSession.Tabnot.AskEvaluatedCellText(cellTag, calloutEvText)
 
            If plBalloonList.Contains(calloutEvText) Then
                'balloon found, remove it from the list so future searches are potentially faster
                plBalloonList.Remove(calloutEvText)
            Else
                'balloon not found, add callout to the "missing" list
                missingBalloons.Add(calloutEvText)
            End If
 
        Next
 
        Dim endTime As DateTime = Now
 
        If missingBalloons.Count = 0 Then
            lw.WriteLine("Great news! All the parts in the list have a corresponding balloon callout.")
        Else
            lw.WriteLine("Hmmm... It seems that " & missingBalloons.Count.ToString & " parts in the list do NOT have corresponding balloon callouts.")
            For Each missing As String In missingBalloons
                lw.WriteLine(missing)
            Next
        End If
 
        Dim elapsedTime As TimeSpan = endTime.Subtract(startTime)
        lw.WriteFullline("elapsed time: " & elapsedTime.ToString)
 
        lw.Close()
 
    End Sub
 
    Function PartListCalloutColumn(ByVal partListTag As Tag) As Tag
 
        Dim numColumns As Integer
        theUfSession.Tabnot.AskNmColumns(partListTag, numColumns)
 
        'Dim numRows As Integer
        'theUfSession.Tabnot.AskNmRows(partListTag, numRows)
 
        'Dim plistPrefs As UFPlist.Prefs = Nothing
        'theUfSession.Plist.AskPrefs(partListTag, plistPrefs)
 
        Dim rowTag As Tag
        theUfSession.Tabnot.AskNthRow(partListTag, 0, rowTag)
 
        For j As Integer = 0 To numColumns - 1
            Dim colTag As Tag
            theUfSession.Tabnot.AskNthColumn(partListTag, j, colTag)
 
            Dim cellTag As Tag
            theUfSession.Tabnot.AskCellAtRowCol(rowTag, colTag, cellTag)
 
            'get the current cell text
            Dim cellText As String = ""
            theUfSession.Tabnot.AskCellText(cellTag, cellText)
            If cellText = "$~C" Then
                'callout column
                Return colTag
 
            End If
 
        Next
 
        Return Nothing
 
    End Function
 
    Sub CollectPartsListBalloons(ByRef theBalloonList As List(Of String), ByVal plSymbolType As Integer)
 
        For Each tempId As Annotations.IdSymbol In theSession.Parts.Work.Annotations.IdSymbols
 
            Dim theIdSymbolBuilder As Annotations.IdSymbolBuilder = theSession.Parts.Work.Annotations.IdSymbols.CreateIdSymbolBuilder(tempId)
 
            If plSymbolType = theIdSymbolBuilder.Type + 1 Then
                'symbol matches type used in parts list
            Else
                'symbol not the type used in parts list, skip it
                Continue For
            End If
 
            'add unique callouts to the list
 
            'assumes the callout is in the ".UpperText" property
            'change this to .LowerText if needed
 
            If Not theBalloonList.Contains(theIdSymbolBuilder.UpperText) Then
                theBalloonList.Add(theIdSymbolBuilder.UpperText)
            End If
 
            theIdSymbolBuilder.Destroy()
 
        Next
 
    End Sub
 
    Public Function GetUnloadOption(ByVal dummy As String) As Integer
 
        'Unloads the image immediately after execution within NX
        GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately
 
    End Function
 
End Module