Measure distance between 2 csys

The following code will look for a saved csys object (not a datum csys feature) that is named "MYCSYS"; if found, it will measure the distance and angles from the current WCS to the saved csys. There is probably a more straightforward way to go about this, it was cobbled together from various other journals that I had on hand.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module Module2

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()
Dim lw As ListingWindow = theSession.ListingWindow

Sub Main()

Dim workPart As Part = theSession.Parts.Work
lw.Open()

Dim myStartObject As CoordinateSystem = theSession.Parts.Work.WCS.CoordinateSystem

Dim startPoint As Point3d = myStartObject.Origin
Dim startOrientation As NXMatrix = myStartObject.Orientation
Dim startCsys(8) As Double
'0-2 = origin point in abs coordinates
startCsys(0) = startPoint.X
startCsys(1) = startPoint.Y
startCsys(2) = startPoint.Z
'3-8 = X & Y vectors in abs coordinates
startCsys(3) = startOrientation.Element.Xx
startCsys(4) = startOrientation.Element.Xy
startCsys(5) = startOrientation.Element.Xz
startCsys(6) = startOrientation.Element.Yx
startCsys(7) = startOrientation.Element.Yy
startCsys(8) = startOrientation.Element.Yz
'NX derives the Z vector from the given X and Y vectors

Dim myEndObject As CoordinateSystem = Nothing
Dim foundEnd As Boolean = False

For Each tempCsys As CoordinateSystem In workPart.CoordinateSystems
If tempCsys.Name = "MYCSYS" Then
myEndObject = tempCsys
foundEnd = True
Exit For
End If
Next

If Not foundEnd Then
lw.WriteLine("End csys not found")
Return
End If

Dim endPoint As Point3d = myEndObject.Origin
Dim endOrientation As NXMatrix = myEndObject.Orientation
Dim endCsys(8) As Double
'0-2 = origin point in abs coordinates
endCsys(0) = endPoint.X
endCsys(1) = endPoint.Y
endCsys(2) = endPoint.Z
'3-8 = X & Y vectors in abs coordinates
endCsys(3) = endOrientation.Element.Xx
endCsys(4) = endOrientation.Element.Xy
endCsys(5) = endOrientation.Element.Xz
endCsys(6) = endOrientation.Element.Yx
endCsys(7) = endOrientation.Element.Yy
endCsys(8) = endOrientation.Element.Yz
'NX derives the Z vector from the given X and Y vectors

Dim fromOrigin() As Double = {startPoint.X, startPoint.Y, startPoint.Z}
Dim fromXAxis() As Double = {startOrientation.Element.Xx, startOrientation.Element.Xy, startOrientation.Element.Xz}
Dim fromYAxis() As Double = {startOrientation.Element.Yx, startOrientation.Element.Yy, startOrientation.Element.Yz}

Dim toOrigin() As Double = {endPoint.X, endPoint.Y, endPoint.Z}
Dim toXAxis() As Double = {endOrientation.Element.Xx, endOrientation.Element.Xy, endOrientation.Element.Xz}
Dim toYAxis() As Double = {endOrientation.Element.Yx, endOrientation.Element.Yy, endOrientation.Element.Yz}

Dim mtx4Transform(15) As Double

theUfSession.Mtx4.CsysToCsys(fromOrigin, fromXAxis, fromYAxis, toOrigin, toXAxis, toYAxis, mtx4Transform)

'rotation angles
Dim rotationAboutX As Double
Dim rotationAboutY As Double
Dim rotationAboutZ As Double

RotationAngles(mtx4Transform, rotationAboutX, rotationAboutY, rotationAboutZ)

lw.WriteLine("")

lw.WriteLine("absolute X distance: " & (endPoint.X - startPoint.X).ToString)
lw.WriteLine("absolute Y distance: " & (endPoint.Y - startPoint.Y).ToString)
lw.WriteLine("absolute Z distance: " & (endPoint.Z - startPoint.Z).ToString)
lw.WriteLine("")
lw.WriteLine("rotation about X: " & rotationAboutX.ToString)
lw.WriteLine("rotation about Y: " & rotationAboutY.ToString)
lw.WriteLine("rotation about Z: " & rotationAboutZ.ToString)

End Sub

Sub RotationAngles(ByVal mtx4x4() As Double, ByRef RX1 As Double, ByRef RY1 As Double, ByRef RZ1 As Double)

'extract euler angles from rotation matrix:

Dim rotationMatrix(8) As Double
theUfSession.Mtx4.AskRotation(mtx4x4, rotationMatrix)

Dim c1, c2, s1 As Double

RX1 = Math.Atan2(rotationMatrix(7), rotationMatrix(8))
c2 = Math.Sqrt(rotationMatrix(0) ^ 2 + rotationMatrix(3) ^ 2)
RY1 = Math.Atan2(-rotationMatrix(6), c2)
s1 = Math.Sin(RX1)
c1 = Math.Cos(RX1)
RZ1 = Math.Atan2(s1 * rotationMatrix(2) - c1 * rotationMatrix(1), c1 * rotationMatrix(4) - s1 * rotationMatrix(5))

'convert angles from radians to degrees
RX1 *= (180 / Math.PI)
RY1 *= (180 / Math.PI)
RZ1 *= (180 / Math.PI)

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module

Now you can use one click. The line
Dim PartName As String = workPart.GetStringAttribute("DB_PART_NAME")
will give you the Name of the Part, If it is not giving, In assembly navigator right click on part and go to properties. In that see which title gives you the part name and replace "DB_PART_NAME" with that. If you want only first five letters of your part name use this line to trim.

PartName = Left(PartName, 5)

Option Strict Off

Imports System
Imports System.IO

Imports NXOpen
Imports NXOpenUI
Imports NXOpen.UI
Imports NXOpen.Utilities
Imports NXOpen.UF

Module NXJournal

Dim theSession As Session = Session.GetSession()
Dim ufs As UFSession = UFSession.GetUFSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()

Sub Main()

Dim lw As ListingWindow = theSession.ListingWindow()
Dim a_body As NXOpen.Tag = NXOpen.Tag.Null
Dim csys As NXOpen.Tag = NXOpen.Tag.Null
lw.Open()
Dim workPart As Part = theSession.Parts.Work
Dim PartName As String = workPart.GetStringAttribute("DB_PART_NAME")
lw.WriteLine("Part Name is " & PartName)
Dim parentFolder As String = IO.Path.GetDirectoryName(workPart.FullPath)

Dim min_corner(2) As Double
Dim directions(2, 2) As Double
Dim distances(2) As Double
Dim distances1(2) As Decimal
Dim decimal1(2) As String
Dim decimal2(2) As String

Dim qtd_desb As String = ""
Dim qtd_acab As String = ""
Dim gap_desb As String = ""
Dim gap_acab As String = ""
Dim espe As String = ""
Dim Name As String = ""

Dim mySelectedObject As NXObject = Nothing

Dim wp As Part = theSession.Parts.Work
Dim objStreamWriter As StreamWriter

'Select a body Forcalculating Boundbox
Dim MyBody As Body = Nothing
If SelectBody("select a body", MyBody) = Selection.Response.Cancel Then
Return
End If
a_body = MyBody.Tag

ufs.Csys.AskWcs(csys)
ufs.Modl.AskBoundingBoxExact(a_body, csys, min_corner, directions, distances)

'Nº ele des
Do
qtd_desb = NXInputBox.GetInputString("Num Des?", "Nº desb", "1")
If qtd_desb = "" Then Exit Sub
Loop Until qtd_desb.Trim.Length > 0

'Nº ele aca
Do
qtd_acab = NXInputBox.GetInputString("Num Aca?", "Nº Acab", "1")
If qtd_acab = "" Then Exit Sub
Loop Until qtd_desb.Trim.Length > 0

'GAP des
Do
gap_desb = NXInputBox.GetInputString("GAP Des?", "GAP desb", "0.50")
If gap_desb = "" Then Exit Sub
Loop Until qtd_desb.Trim.Length > 0

'GAP aca
Do
gap_acab = NXInputBox.GetInputString("GAP Aca?", "GAP acab", "0.30")
If gap_acab = "" Then Exit Sub
Loop Until qtd_desb.Trim.Length > 0

'Mirror
Do
espe = NXInputBox.GetInputString("Mirror?", "Mirror?", " ")
If espe = "" Then Exit Sub
Loop Until qtd_desb.Trim.Length > 0

Dim myStartObject As CoordinateSystem = theSession.Parts.Work.WCS.CoordinateSystem

Dim startPoint As Point3d = myStartObject.Origin
Dim startOrientation As NXMatrix = myStartObject.Orientation

Dim foundEnd As Boolean = False

Dim endPoint As Point3d
Dim rotationAboutX As Double
Dim rotationAboutY As Double
Dim rotationAboutZ As Double

' Distances and rotation between ele csys and main body csys
For Each myFeature As Features.Feature In theSession.Parts.Work.Features.GetFeatures()
If myFeature.GetFeatureName = "Datum Coordinate System(0)" Then
Dim csysTag As Tag
Dim originTag As Tag
Dim daxesTags(2) As Tag
Dim dplanesTags(2) As Tag

theUfSession.Modl.AskDatumCsysComponents(myFeature.Tag, csysTag, originTag, daxesTags, dplanesTags)
Dim theCsys As CoordinateSystem = Utilities.NXObjectManager.Get(csysTag)

endPoint = theCsys.Origin

Dim endOrientation As NXMatrix = theCsys.Orientation

Dim fromOrigin() As Double = {startPoint.X, startPoint.Y, startPoint.Z}
Dim fromXAxis() As Double = {startOrientation.Element.Xx, startOrientation.Element.Xy, startOrientation.Element.Xz}
Dim fromYAxis() As Double = {startOrientation.Element.Yx, startOrientation.Element.Yy, startOrientation.Element.Yz}

Dim toOrigin() As Double = {endPoint.X, endPoint.Y, endPoint.Z}
Dim toXAxis() As Double = {endOrientation.Element.Xx, endOrientation.Element.Xy, endOrientation.Element.Xz}
Dim toYAxis() As Double = {endOrientation.Element.Yx, endOrientation.Element.Yy, endOrientation.Element.Yz}

Dim mtx4Transform(15) As Double

theUfSession.Mtx4.CsysToCsys(fromOrigin, fromXAxis, fromYAxis, toOrigin, toXAxis, toYAxis, mtx4Transform)

RotationAngles(mtx4Transform, rotationAboutX, rotationAboutY, rotationAboutZ)

foundEnd = True
Exit For
End If
Next

If Not foundEnd Then
lw.WriteLine("End csys not found")
Return
End If

'Show all values

lw.WriteLine("")
lw.WriteLine(PartName & "_" & Name)

lw.WriteLine("X=" & Replace(FormatNumber(distances(0), 2).ToString, ",", ".") & ", " & _
"Y=" & Replace(FormatNumber(distances(1), 2).ToString, ",", ".") & ", " & _
"Z=" & Replace(FormatNumber(distances(2), 2).ToString, ",", "."))
lw.WriteLine("Qtd des: " & qtd_desb)
lw.WriteLine("Qtd aca: " & qtd_acab)
lw.WriteLine("Gap des: " & gap_desb)
lw.WriteLine("Gap aca: " & gap_acab)
lw.WriteLine("Mirror: " & espe)
lw.WriteLine("X= " & Replace(FormatNumber((endPoint.X - startPoint.X), 2).ToString, ",", ".") & ", " & _
"Y= " & Replace(FormatNumber((endPoint.Y - startPoint.Y), 2).ToString, ",", ".") & ", " & _
"Z= " & Replace(FormatNumber((endPoint.Z - startPoint.Z), 2).ToString, ",", ".") & ", " & _
"C= " & Replace(FormatNumber((rotationAboutY.ToString), 2).ToString, ",", "."))

' Write in the TXT
objStreamWriter = New StreamWriter(parentFolder & "\2D\COTAS\" & Name & ".txt")

End Sub

Function body_init_proc(ByVal select_ As IntPtr, ByVal userdata As IntPtr) As Integer

Dim num_triples As Integer = 1
Dim mask_triples(0) As UFUi.Mask
mask_triples(0).object_type = UFConstants.UF_solid_type
mask_triples(0).object_subtype = UFConstants.UF_solid_body_subtype
mask_triples(0).solid_type = UFConstants.UF_UI_SEL_FEATURE_BODY

ufs.Ui.SetSelMask(select_, UFUi.SelMaskAction.SelMaskClearAndEnableSpecific, num_triples, mask_triples)

Return UFConstants.UF_UI_SEL_SUCCESS

End Function

Function SelectBody(ByVal prompt As String, ByRef selObj As TaggedObject) As Selection.Response

Dim theUI As UI = UI.GetUI
Dim title As String = "Select a solid body"
Dim includeFeatures As Boolean = False
Dim keepHighlighted As Boolean = False
Dim selAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific
Dim cursor As Point3d
Dim scope As Selection.SelectionScope = Selection.SelectionScope.AnyInAssembly
Dim selectionMask_array(0) As Selection.MaskTriple

With selectionMask_array(0)
.Type = UFConstants.UF_solid_type
.SolidBodySubtype = UFConstants.UF_UI_SEL_FEATURE_SOLID_BODY
End With

Dim resp As Selection.Response = theUI.SelectionManager.SelectTaggedObject(prompt, _
title, scope, selAction, _
includeFeatures, keepHighlighted, selectionMask_array, _
selobj, cursor)
If resp = Selection.Response.ObjectSelected OrElse resp = Selection.Response.ObjectSelectedByName Then
Return Selection.Response.Ok
Else
Return Selection.Response.Cancel
End If

End Function

Sub RotationAngles(ByVal mtx4x4() As Double, ByRef RX1 As Double, ByRef RY1 As Double, ByRef RZ1 As Double)

'extract euler angles from rotation matrix:

Dim rotationMatrix(8) As Double
theUfSession.Mtx4.AskRotation(mtx4x4, rotationMatrix)

Dim c1, c2, s1 As Double

RX1 = Math.Atan2(rotationMatrix(7), rotationMatrix(8))
c2 = Math.Sqrt(rotationMatrix(0) ^ 2 + rotationMatrix(3) ^ 2)
RY1 = Math.Atan2(-rotationMatrix(6), c2)
s1 = Math.Sin(RX1)
c1 = Math.Cos(RX1)
RZ1 = Math.Atan2(s1 * rotationMatrix(2) - c1 * rotationMatrix(1), c1 * rotationMatrix(4) - s1 * rotationMatrix(5))

'convert angles from radians to degrees
RX1 *= (180 / Math.PI)
RY1 *= (180 / Math.PI)
RZ1 *= (180 / Math.PI)

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

GetUnloadOption = UFConstants.UF_UNLOAD_IMMEDIATELY

End Function

End Module