How to perform sketch reattach via NXOpen (vb)

I ran into a situation a few years ago where internal features were causing issues. If a feature is internal to another, the .IsInternal property will return "True". There is probably a very simple way to get the "containing feature", but I could not find it. What I noticed is that the timestamp of the internal feature will be the same as the containing feature. I used this fact to keep track of internal vs. external features.

I wrote some test code while working on this issue. It runs through the feature collection and sorts the features into "internal" and "external" groups. I used dictionaries to keep track of which was which. The code below simply reports out all the features found, but you could pass in a specific feature to the "internal feature dictionary" to find out its containing feature.

The code below is my old test code. I've not reviewed it recently and it could probably use some polish, but it still seems to work.

Option Strict Off
Imports System
Imports System.Collections.Generic
Imports NXOpen

Module Module1

Sub Main()

Dim theSession As Session = Session.GetSession()
If IsNothing(theSession.Parts.BaseWork) Then
'active part required
Return
End If

Dim workPart As Part = theSession.Parts.Work
Dim lw As ListingWindow = theSession.ListingWindow
lw.Open()

Const undoMarkName As String = "report internal features"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

'*************************************************************************************************
'Query the features of the current work part
'
'Create some dictionary objects to hold information on internal features.
'
'internal feature = key; containing feature = value
Dim internalFeatureDictionary As New Dictionary(Of Features.Feature, Features.Feature)
'"container" feature = key, list of internal features = value
Dim externalFeatureDictionary As New Dictionary(Of Features.Feature, List(Of Features.Feature))

Dim curTimeStamp As Integer = -1
Dim containerFeature As Features.Feature = Nothing
Dim internalFeats As New List(Of Features.Feature)
For Each tempFeat As Features.Feature In workPart.Features

If tempFeat.Timestamp = curTimeStamp Then

If tempFeat.IsInternal Then
'lw.WriteLine("adding feature to 'internal' list")
internalFeats.Add(tempFeat)

Else 'same timestamp, external feature
containerFeature = tempFeat

End If

Else 'different timestamp

If Not IsNothing(containerFeature) Then
externalFeatureDictionary.Add(containerFeature, New List(Of Features.Feature)(internalFeats))
For Each temp As Features.Feature In internalFeats
internalFeatureDictionary.Add(temp, containerFeature)
Next
End If
internalFeats.Clear()
curTimeStamp = tempFeat.Timestamp

If tempFeat.IsInternal Then
internalFeats.Add(tempFeat)
containerFeature = Nothing

Else 'different timestamp, external feature
containerFeature = tempFeat

End If

End If

Next

If Not IsNothing(containerFeature) Then
externalFeatureDictionary.Add(containerFeature, New List(Of Features.Feature)(internalFeats))
For Each temp As Features.Feature In internalFeats
internalFeatureDictionary.Add(temp, containerFeature)
Next
End If
'
'End of Query
'*************************************************************************************************

'Report out on the features contained in the work part using the dictionary objects created earlier.
For Each temp As Features.Feature In workPart.Features
lw.WriteLine("feature: " & temp.GetFeatureName & " [" & temp.Tag.ToString & "]")
If internalFeatureDictionary.ContainsKey(temp) Then
lw.WriteLine(" is internal to: " & internalFeatureDictionary.Item(temp).GetFeatureName & " [" & internalFeatureDictionary.Item(temp).Tag.ToString & "]")
End If

If externalFeatureDictionary.ContainsKey(temp) Then
If externalFeatureDictionary.Item(temp).Count > 0 Then
lw.WriteLine(" contains the features:")
For Each internalFeat As Features.Feature In externalFeatureDictionary.Item(temp)
lw.WriteLine(" " & internalFeat.GetFeatureName & " [" & internalFeat.Tag.ToString & "]")
Next

Else
lw.WriteLine(" contains no internal features")
End If
End If

lw.WriteLine("")
Next

lw.Close()

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module