extracting object attributes

I plan on looking at this, but I've been caught up in other projects.

The code below illustrates how to associatively extract an attribute value and add it to a tabular note. It will prompt you to select the tabular note, then it will prompt you to select a component. The component display name will be written in the first column (starting in the second row, the first row is assumed to contain header information) and the "Material" attribute value will be written in the 2nd column. It will continue to prompt for a component until you select the "cancel" button.

The code was written for NX 8.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module Module1

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()

Dim workPart As Part = theSession.Parts.Work
Dim lw As ListingWindow = theSession.ListingWindow

Sub Main()

If IsNothing(theSession.Parts.BaseWork) Then
'active part required
Return
End If

lw.Open()

Const undoMarkName As String = "NXJ journal"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

Dim theTabNote As Annotations.TableSection
If SelectTabNoteSection("Select a tabular note", theTabNote) = Selection.Response.Cancel Then
Return
End If

Dim theComponent As Assemblies.Component
'starting row number of tabular note
Dim row As Integer = 1
Dim attTitle As String = "Material"

Do Until SelectComponent("select a component", theComponent) = Selection.Response.Cancel
'does material attribute exist?
If theComponent.HasUserAttribute(attTitle, NXObject.AttributeType.String, 0) Then
'lw.WriteLine("has material attribute")
AddComponentInfo(theComponent, attTitle, row, theTabNote)
row += 1
Else
lw.WriteLine("component, " & theComponent.DisplayName & ", does not have the attribute: " & attTitle)
End If
Loop

lw.Close()

End Sub

Function SelectTabNoteSection(ByVal prompt As String, ByRef selObj As TaggedObject) As Selection.Response

Dim theUI As UI = UI.GetUI
Dim title As String = "Select a tabular note"
Dim includeFeatures As Boolean = False
Dim keepHighlighted As Boolean = False
Dim selAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific
Dim cursor As Point3d
Dim scope As Selection.SelectionScope = Selection.SelectionScope.WorkPart
Dim selectionMask_array(0) As Selection.MaskTriple

With selectionMask_array(0)
.Type = UFConstants.UF_tabular_note_type
.Subtype = UFConstants.UF_tabular_note_section_subtype
End With

Dim resp As Selection.Response = theUI.SelectionManager.SelectTaggedObject(prompt, _
title, scope, selAction, _
includeFeatures, keepHighlighted, selectionMask_array, _
selObj, cursor)
If resp = Selection.Response.ObjectSelected OrElse resp = Selection.Response.ObjectSelectedByName Then
Return Selection.Response.Ok
Else
Return Selection.Response.Cancel
End If

End Function

Function SelectComponent(ByVal prompt As String, ByRef selObj As TaggedObject) As Selection.Response

Dim theUI As UI = UI.GetUI
Dim title As String = "Select a component"
Dim includeFeatures As Boolean = False
Dim keepHighlighted As Boolean = False
Dim selAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific
Dim cursor As Point3d
Dim scope As Selection.SelectionScope = Selection.SelectionScope.AnyInAssembly
Dim selectionMask_array(0) As Selection.MaskTriple

With selectionMask_array(0)
.Type = UFConstants.UF_component_type
.Subtype = UFConstants.UF_all_subtype
End With

theUfSession.Ui.SetCursorView(0)

Dim resp As Selection.Response = theUI.SelectionManager.SelectTaggedObject(prompt, _
title, scope, selAction, _
includeFeatures, keepHighlighted, selectionMask_array, _
selobj, cursor)
If resp = Selection.Response.ObjectSelected OrElse resp = Selection.Response.ObjectSelectedByName Then
Return Selection.Response.Ok
Else
Return Selection.Response.Cancel
End If

End Function

Sub AddComponentInfo(ByVal tempComp As Assemblies.Component,
ByVal attributeTitle As String,
ByVal row As Integer,
ByRef tableNote As Annotations.TableSection)

Dim tabularNoteTag As Tag
theUfSession.Tabnot.AskTabularNoteOfSection(tableNote.Tag, tabularNoteTag)

Dim numRows As Integer
theUfSession.Tabnot.AskNmRowsInSection(tableNote.Tag, numRows)

If row > numRows Then
'add code to create new row

'for this example code, we'll just exit the sub
Return
End If

Dim numCols As Integer
theUfSession.Tabnot.AskNmColumns(tabularNoteTag, numCols)

Dim rowTag As Tag
theUfSession.Tabnot.AskNthRowInSection(tableNote.Tag, row, rowTag)

Dim colTag As Tag
theUfSession.Tabnot.AskNthColumn(tabularNoteTag, 0, colTag)

Dim cellTag As Tag
theUfSession.Tabnot.AskCellAtRowCol(rowTag, colTag, cellTag)

'add component name to first column
theUfSession.Tabnot.SetCellText(cellTag, tempComp.DisplayName)

'get associative text for attribute
Dim associativeText1 As Annotations.AssociativeText
associativeText1 = workPart.Annotations.CreateAssociativeText()

Dim text1 As String
text1 = associativeText1.GetObjectAttributeText(tempComp, attributeTitle)

associativeText1.Dispose()

'add attribute text to column 2
theUfSession.Tabnot.AskNthColumn(tabularNoteTag, 1, colTag)
theUfSession.Tabnot.AskCellAtRowCol(rowTag, colTag, cellTag)

theUfSession.Tabnot.SetCellText(cellTag, text1)

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module

I was working off the information that you gave on Wed, 05/27/2015 - 10:01

"Yes it is a plain tabular note and not a part list. We are using nx8."

A re-write for NX 7.5 is not a trivial task. I don't think that I'll have time to look at it today.
I'll have to fire up 7.5 and re-familiarize myself on how the mass is handled. Can you give an example of how you currently handle the mass attribute? Do you create it yourself or is it handled automatically?