Points and Information

While poking around the GTAC solution center, I found some code that will report the ID of the selected object. Perhaps this will simplify your code.

Code written by Amy Webster of GTAC fame.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module NXJournal

Dim s As Session = Nothing
Dim ufs As UFSession = Nothing
Dim lw As ListingWindow = Nothing

Sub Main
s = Session.GetSession()
lw = s.ListingWindow
ufs = NXOpen.UF.UFSession.GetUFSession()

Dim object1 As NXObject = SelectAnObject("Report Object ID")
Dim handle As String = Nothing
Dim fileData As String = Nothing
Dim ID as UInteger = 0
Dim version as UInteger = 0

Do While object1 isnot nothing
handle = ufs.Tag.AskHandleOfTag(object1.Tag)
ufs.Tag.DecomposeHandle(handle, fileData, ID, version)
ECHO("ID = " & ID)

object1 = SelectAnObject("Report Object ID")
Loop
End Sub

Function SelectAnObject(ByVal prompt As String) As NXObject

Dim selobj As NXObject = Nothing
Dim theUI As UI = UI.GetUI
Dim cursor As Point3d
Dim typeArray() As Selection.SelectionType = _
{Selection.SelectionType.All, _
Selection.SelectionType.Faces, _
Selection.SelectionType.Edges}

Dim resp As Selection.Response = theUI.SelectionManager.SelectObject( _
prompt, "Select an object", _
Selection.SelectionScope.AnyInAssembly, _
False, typeArray, selobj, cursor)

Return selobj
End Function

Sub Echo(ByVal output As String)
lw.Open()
lw.WriteLine(output)
ufs.UF.PrintSyslog(output & vbCrLf, False)
End Sub

End Module

This version allows you to select multiple point objects and writes the information window to a single file.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module Module1

Sub Main()

Dim theSession As Session = Session.GetSession()
Dim workPart As Part = theSession.Parts.Work
Dim lw As ListingWindow = theSession.ListingWindow
Dim myDocs As String
myDocs = Environment.GetFolderPath(Environment.SpecialFolder.MyDocuments)
Dim thePoints() As NXObject
lw.Open()

If SelectPoints("Select points", thePoints) = Selection.Response.Cancel Then
Return
End If

Dim outputFile As String = IO.Path.Combine(myDocs, "point_info.txt")

If IO.File.Exists(outputFile) Then
Try
IO.File.Delete(outputFile)
Catch ex As Exception
MsgBox(ex.Message, MsgBoxStyle.OkOnly, "Error deleting file")
End Try
End If

lw.SelectDevice(ListingWindow.DeviceType.File, outputFile)
theSession.Information.DisplayObjectsDetails(thePoints)
lw.Close()
'flush file buffer by changing listing window device
lw.SelectDevice(ListingWindow.DeviceType.Window, "")

MsgBox("Output written to " & outputFile)

End Sub

Function SelectPoints(ByVal prompt As String, byRef selObj() as NXObject) As Selection.Response

Dim theUI As UI = UI.GetUI
Dim title As String = "Select points"
Dim includeFeatures As Boolean = False
Dim keepHighlighted As Boolean = False
Dim selAction As Selection.SelectionAction = Selection.SelectionAction.ClearAndEnableSpecific
Dim scope As Selection.SelectionScope = Selection.SelectionScope.WorkPart
Dim selectionMask_array(0) As Selection.MaskTriple

With selectionMask_array(0)
.Type = UFConstants.UF_point_type
.Subtype = UFConstants.UF_point_subtype
End With

Dim resp As Selection.Response = theUI.SelectionManager.SelectObjects(prompt, _
title, scope, selAction, _
includeFeatures, keepHighlighted, selectionMask_array, _
selobj)
If resp = Selection.Response.Ok Then
Return Selection.Response.Ok
Else
Return Selection.Response.Cancel
End If

End Function

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image when the NX session terminates
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

End Function

End Module