Read a text file

Often the output of one program is used as the input of another; a common method of transferring this information is through the use of files. For instance, an industrial designer may make a clay concept model of a new product; to begin the digital modeling process the model may be 3D scanned or measured with a coordinate measuring machine (CMM). The scanner or CMM doesn't need to know anything about the CAD program that will be used, it can output point data to a file which can then be imported to the CAD software as "point clouds" and subsequently used to recreate the surfaces. This tutorial will show how to read a text file and parse point information from it to draw lines between the given points.

File types

On Windows systems file names take the form [filename].[extension]; generally the extension is 3 letters long (though the filesystem your OS version uses may allow more) and they help the OS and the user to quickly identify the type of file. Even though there are 100's of different file types, they all basically belong to one of two categories: text file or binary file. Typical text files you will run across include: .txt (obviously), .log, .csv, .x_t. Some common binary files include: .exe, .dll, .mp3, .jpg, .prt. Try opening a few different files in notepad (or your favorite text editor, but remember to make a backup first and DO NOT SAVE THE FILE IN THE TEXT EDITOR); if you can make sense of it, it is likely a text file - if you are confronted with a mass of seeming gibberish, it is either a binary file or monkey test subject #27649's attempt at rewriting Shakespear's Hamlet. So even though we are reading text files, we are not limited to only files with the .txt extension.

.NET StreamReader

.NET provides everything we need to read text files; specifically, we will be using a "stream reader" object. For our input file, each line will represent a single point; X, Y, and Z values separated by commas.The stream reader will allow us to read the input file line by line. Our strategy will be to read a line, split it into components (XYZ), assign the components to a corresponding Point3D, and on the second and subsequent points - draw a line from the previous point to the current point.

Download the code here

[vbnet]'NXJournaling.com
'example: read text file
'each line of the input file should be 3 numbers separated by commas (#.###, #.###, #.###)
'the numbers will be interpreted as line start/end points

Option Strict Off
Imports System
Imports System.IO
Imports System.Windows.Forms
Imports NXOpen

Module Module1

Sub Main()
Dim openFileDialog1 As New OpenFileDialog()

openFileDialog1.Filter = "txt files (*.txt)|*.txt|All files (*.*)|*.*"
openFileDialog1.FilterIndex = 1
openFileDialog1.RestoreDirectory = True

If openFileDialog1.ShowDialog() = DialogResult.OK Then
Dim theSession As Session = Session.GetSession()
Dim workPart As Part = theSession.Parts.Work
Dim line As String
Dim startPoint As Point3d = nothing
Dim endPoint As Point3d
Dim firstPass as Boolean = True
Dim delim As Char() = {","c}

Using sr As StreamReader = New StreamReader(openFileDialog1.FileName)
Try
line = sr.ReadLine()
While Not line Is Nothing
Dim strings As String() = line.Split(delim)
endPoint.x = Double.Parse(strings(0))
endPoint.y = Double.Parse(strings(1))
endPoint.z = Double.Parse(strings(2))
If firstPass Then
firstPass = False
Else
'create a line from startpoint to endpoint
workPart.Curves.CreateLine(startPoint, endPoint)
End If
startPoint = endPoint

line = sr.ReadLine()
End While
Catch E As Exception
MessageBox.Show(E.Message)
End Try
End Using
End If
End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image when the NX session terminates
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

End Function

End Module [/vbnet]

Some items of note:
You may have noticed we didn't use the usual Dim statement before the StreamReader variable. The Using... End Using block will dispose of the stream reader object at the proper time; otherwise, we would have to call the stream reader's Close method ourselves to mark it for garbage collection. The Using... End Using block allows the compiler to do the work for us and we can be assured the stream reader will be disposed of properly; had we used Dim sr as StreamReader... and forgotten the sr.Close statement, the compiler would not warn us (since it doesn't know when or if we want to close the stream reader).

The Double.Parse method is used to convert the text to a numeric value (of type double). If your computer's regional settings use something other than the decimal point for the decimal separator (the comma, for instance), you likely got an error message along the lines of "input in an incorrect format". We can correct this by specifying what format we want to read; the next bit of journal code will show how to do this.

All input points were interpreted into the absolute coordinate system of the part. The next journal will include a function to map the points to the WCS.

Improved Code

This next journal includes a System.Globalization.CultureInfo object that is set to US english ("en-US"), since that is the format that we expect the input strings to use (change the journal accordingly for your specific requirements). Now when the values are parsed, we specify the text to parse along with the culture info to interpret it properly. This code should now run properly regardless of the computer's regional settings.

Lastly, there is a function included (taken from a GTAC example) that converts the point coordinates to the WCS.

[vbnet]
'NXJournaling.com
'example: read text file
'each line of the input file should be 3 numbers separated by commas (#.###, #.###, #.###)
'the numbers will be interpreted as line start/end points

Option Strict Off
Imports System
Imports System.IO
Imports System.Windows.Forms
Imports NXOpen
Imports NXOpen.UF

Module Module1
Dim ufs As UFSession = UFSession.GetUFSession

Sub Main()
Dim openFileDialog1 As New OpenFileDialog()

openFileDialog1.Filter = "txt files (*.txt)|*.txt|All files (*.*)|*.*"
openFileDialog1.FilterIndex = 1
openFileDialog1.RestoreDirectory = True

If openFileDialog1.ShowDialog() = DialogResult.OK Then
Dim theSession As Session = Session.GetSession()
Dim workPart As Part = theSession.Parts.Work
Dim line As String
Dim startPoint As Point3d = nothing
Dim endPoint As Point3d
Dim i As Integer = 0
Dim firstPass as Boolean = True
Dim delim As Char() = {","c}
Dim USculture As system.globalization.CultureInfo = New System.Globalization.CultureInfo("en-US")

Using sr As StreamReader = New StreamReader(openFileDialog1.FileName)
Try
line = sr.ReadLine()
While Not line Is Nothing
Dim strings As String() = line.Split(delim)
endPoint.x = Double.Parse(strings(0), USculture)
endPoint.y = Double.Parse(strings(1), USCulture)
endPoint.z = Double.Parse(strings(2), USCulture)
endPoint = Abs2WCS(endPoint)
If firstPass Then
firstPass = False
Else
'create a line from startpoint to endpoint
workPart.Curves.CreateLine(startPoint, endPoint)
End If
startPoint = endPoint
line = sr.ReadLine()
End While
Catch E As Exception
MessageBox.Show(E.Message)
End Try
End Using
End If

End Sub
'&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
'Date: 11/18/2010
'Subject: Sample NX Open .NET Visual Basic routine : map point from absolute to wcs
'
'Note: function taken from GTAC example code

Function Abs2WCS(ByVal inPt As Point3d) As Point3d
Dim pt1(2), pt2(2) As Double

pt1(0) = inPt.X
pt1(1) = inPt.Y
pt1(2) = inPt.Z

ufs.Csys.MapPoint(UFConstants.UF_CSYS_ROOT_COORDS, pt1, _
UFConstants.UF_CSYS_ROOT_WCS_COORDS, pt2)

Abs2WCS.X = pt2(0)
Abs2WCS.Y = pt2(1)
Abs2WCS.Z = pt2(2)

End Function
'&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&&
Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image when the NX session terminates
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

End Function

End Module
[/vbnet]

Conclusion

This article shows how to use .NET's stream reader to read a text file line by line. As long as you know how to interpret the input file, you can write custom code to read it and do something useful with it in NX.