How to get the maximum principal stress values and nodes and output them

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module ResultAccessPerf

' Explicit Activation
' This entry point is used to activate the application explicitly
Sub Main()

Dim theSession As Session = Session.GetSession()
Dim theUI As UI = UI.GetUI()
Dim theUfSession As UFSession = UFSession.GetUFSession()

' TODO: Add your application code here

' Define the listing window so we can write text information
Dim theLw As ListingWindow = theSession.ListingWindow
theLw.Open()

' Define the message box to report any errors
Dim theNxMessageBox As NXMessageBox = theUI.NXMessageBox

' Get the current work part
Dim basePart As BasePart = theSession.Parts.BaseWork

' Verify that it is a SIM part
Dim simPart As CAE.SimPart = TryCast(basePart, CAE.SimPart)
If simPart Is Nothing Then
theNxMessageBox.Show("NX Result Access", NXMessageBox.DialogType.Error, _
"The current work part is not a SIM part")
Return
End If

' Loop through all solutions in the SIM
For Each solution As CAE.SimSolution In simPart.Simulation.Solutions.ToArray

theLw.WriteLine("Solution: [" + solution.Name + _
"] Solver Type: [" + solution.SolverType + _
"] Solution Type: [" + solution.SolutionType + _
"] Analysis Type: [" + solution.AnalysisType + "]")

' Create a Result object for the current solution
Dim resultManager As CAE.ResultManager = theSession.ResultManager
Dim solResult As CAE.Result = resultManager.CreateSolutionResult(solution)

' Loop through all loadcases in the result
For Each loadcase As CAE.BaseLoadcase In solResult.GetLoadcases

theLw.WriteLine(vbNewLine + " Loadcase: [" + loadcase.Name + "]")

' Loop through all iterations in the loadcase
For Each iteration As CAE.BaseIteration In loadcase.GetIterations

theLw.WriteLine(" Iteration: [" + iteration.Name + _
"] Type: [" + iteration.Type.ToString + "]")

' Loop through each result type in the iteration
For Each baseResultType As CAE.BaseResultType In iteration.GetResultTypes

Dim resultType As CAE.ResultType = TryCast(baseResultType, CAE.ResultType)

theLw.WriteLine(" ResultType = [" + resultType.Name + "]")
theLw.WriteLine(" Datatype = [" + resultType.Datatype.ToString + "]")
theLw.WriteLine(" Location = [" + resultType.Location.ToString + "] ")
theLw.WriteLine(" Quatitiy = [" + resultType.Quantity.ToString + "] ")
theLw.WriteLine(" Complex = [" + resultType.Complex.ToString + "]")
theLw.WriteLine(" Title = [" + resultType.Title + "]")
theLw.WriteLine(" SubTitle = [" + resultType.Subtitle + "]")
theLw.WriteLine(" UserName = [" + resultType.UserName + "]")

' Loop through the components available for this result type
Dim components() As CAE.Result.Component = Nothing
resultType.AskComponents(components)

Dim compList As String = Nothing
For Each component As CAE.Result.Component In components
compList += " [" + component.ToString + "]"
Next component

theLw.WriteLine(" Components =" + compList)

' Loop through each section in the ResultType
' Note that sections do not exist for all result types
Dim sections() As CAE.Result.Section = resultType.GetSectionDefined
If sections.Length > 0 Then

Dim sectionList As String = Nothing
For Each section As CAE.Result.Section In resultType.GetSectionDefined
sectionList += " [" + section.ToString + "]"
Next section

theLw.WriteLine(" Sections =" + sectionList)

End If

' Get the ResultAccess object
Dim resultParam As CAE.ResultParameters = resultManager.CreateResultParameters
resultParam.SetGenericResultType(resultType)
resultParam.SetResultComponent(components(0))
resultParam.SetCoordinateSystem(CAE.Result.CoordinateSystem.AbsoluteRectangular)

Dim resultAccess As CAE.ResultAccess = resultManager.CreateResultAccess(solResult, resultParam)

' Print displacements at node 65
If resultType.Quantity = CAE.Result.Quantity.Displacement And _
resultType.Location = CAE.Result.Location.Nodal Then

' Get the index for the node label
Dim nodeIndex As Integer = solResult.AskNodeIndex(65)

' Get the result values for this node
Dim nodeValues() As Double = Nothing
resultAccess.AskNodalResultAllComponents(nodeIndex, nodeValues)

theLw.WriteLine(vbNewLine + " Node 65 Displacements:")
For i As Integer = 0 To nodeValues.Length - 1
theLw.WriteLine(" Component: [" + components(i).ToString + _
"] Value: [" + nodeValues(i).ToString + "]")
Next

End If

' Print stresses at element 25
If resultType.Quantity = CAE.Result.Quantity.Stress And _
resultType.Location = CAE.Result.Location.ElementNodal Then

Dim elementIndex As Integer = solResult.AskElementIndex(25)
Dim elemNodeIdxs() As Integer = Nothing
Dim iNumComponents As Integer
Dim elementValues() As Double = Nothing
resultAccess.AskElementNodalResultAllComponents(elementIndex, elemNodeIdxs, _
iNumComponents, elementValues)

theLw.WriteLine(vbNewLine + " Element 25 Stresses:")
For i As Integer = 0 To elemNodeIdxs.Length - 1

Dim nodeLabel As Integer = solResult.AskNodeLabel(elemNodeIdxs(i))
theLw.WriteLine(" Node: [" + nodeLabel.ToString + "]")

For j As Integer = 0 To iNumComponents - 1

Dim valueIndex As Integer = i * iNumComponents + j

theLw.WriteLine(" Component: [" + components(j).ToString + _
"] Value: [" + elementValues(valueIndex).ToString + "]")
Next j

Next i

End If

' Clean up the ResultAccess and ResultParameters objects
resultManager.DeleteResultAccess(resultAccess)
resultManager.DeleteResultParameters(resultParam)

theLw.WriteLine(vbNewLine)

Next baseResultType

Next iteration

Next loadcase

' Clean up the Result object
resultManager.DeleteResult(solResult)

Next solution

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

'----Other unload options-------
'Unloads the image when the NX session terminates
'GetUnloadOption = NXOpen.Session.LibraryUnloadOption.AtTermination

'Unloads the image explicitly, via an unload dialog
'GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Explicitly
'-------------------------------

End Function