Displayed Part Properties to Excel

Here's the latest code I have; the formatting is not exactly the same as what you get with the "export to spredsheet" command but the information is the same.

Option Strict Off
Imports System
Imports NXOpen
Imports NXOpen.UF

Module Module1

Sub Main()

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession()
Dim theUISession As UI = UI.GetUI
If IsNothing(theSession.Parts.BaseWork) Then
'active part required
Return
End If

Dim workPart As Part = theSession.Parts.Work
Dim displayPart As Part = theSession.Parts.Display
Dim lw As ListingWindow = theSession.ListingWindow
lw.Open()

Const undoMarkName As String = "NXJ journal"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

Dim theAttributes() As NXObject.AttributeInformation
theAttributes = displayPart.GetUserAttributes(True)

'change excelFileName to meet your needs
'create the excel file before running this journal
Const excelFileName As String = "C:\Temp\display_part_attributes.xlsx"
Dim row As Long = 1
Dim column As Long = 1

'create Excel object
Dim objExcel = CreateObject("Excel.Application")
If objExcel Is Nothing Then
theUISession.NXMessageBox.Show("Error", NXMessageBox.DialogType.Error, "Could not start Excel, journal exiting")
theSession.UndoToMark(markId1, "journal")
Exit Sub
End If

'open Excel file
Dim objWorkbook = objExcel.Workbooks.Open(excelFileName)
If objWorkbook Is Nothing Then
theUISession.NXMessageBox.Show("Error", NXMessageBox.DialogType.Error, "Could not open Excel file: " & excelFileName & ControlChars.NewLine & "journal exiting.")
theSession.UndoToMark(markId1, "journal")
Exit Sub
End If

objExcel.visible = True

'create title row
objExcel.Cells(row, 1) = "Title"
objExcel.cells(row, 2) = "Value"
objExcel.cells(row, 3) = "Units"
objExcel.cells(row, 4) = "Category"
objExcel.cells(row, 5) = "Type"
objExcel.cells(row, 6) = "Read-only"
objExcel.cells(row, 7) = "Inherited"
row += 1

Dim title As String
Dim value As String
Dim attType As String
Dim attReadOnly As String
Dim attInherited As String

For Each temp As NXObject.AttributeInformation In theAttributes

title = temp.Title
value = ""
'lw.WriteLine("title: " & title)

Select Case temp.Type
Case Is = NXObject.AttributeType.Boolean
value = temp.BooleanValue.ToString
attType = "Boolean"
Case Is = NXObject.AttributeType.Integer
value = temp.IntegerValue.ToString
attType = "Integer"
Case Is = NXObject.AttributeType.Real
value = temp.RealValue.ToString
attType = "Real"
Case Is = NXObject.AttributeType.String
value = temp.StringValue
attType = "String"
Case Is = NXObject.AttributeType.Time
value = temp.TimeValue.ToString
attType = "Time"
Case Else
value = "value type not supported by this journal"
attType = "N/A"
End Select

'lw.WriteLine("value: " & value)

'lw.WriteLine("")

objExcel.Cells(row, 1) = title
objExcel.cells(row, 2) = value
If Not IsNothing(temp.Unit) Then
objExcel.cells(row, 3) = temp.Unit.Name
End If
objExcel.cells(row, 4) = temp.Category
objExcel.cells(row, 5) = attType
objExcel.cells(row, 6) = temp.Locked.ToString
objExcel.cells(row, 7) = temp.Inherited.ToString

row += 1

Next

'objExcel.Quit()
objWorkbook = Nothing
objExcel = Nothing

lw.Close()

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module