Replacing Text In A Table Cell

When you want to find a specific entity when running a journal, the usual advice is to give the target entity a unique name or attribute. When the journal runs, it can find the entity based on the name or attribute and perform some action on it. However, tabular notes in NX are an exception to this rule. I've found no way to apply a name or attribute to a specific cell in a tabular note.

Working with tabular notes in interactive NX is fairly straightforward; but the object model and API calls to manipulate them seem overly convoluted (IMHO). While I've not yet found a way to name a specific cell, you can give a name to a tabular note section (which is not the same as the tabular note itself, btw).

The code below is a bit of a work-around. You will need to know the row and column number of the cell you want to change. To see the code in action, do the following:

• open an NX file and create a new tabular note
• right click on the tabular note -> properties -> general tab => enter "TABLETEST" for the object name.
• run the journal. The text "testing" should show up in the cell at the first row, first column (top left corner).
• edit the constants as desired at the beginning of Sub Main (or edit the code to provide inputs for the user).

'NXJournaling.com
'January 16, 2023

'Find a tabular note with the specified name and change the text of the specified cell.
'Change the constants at the beginning of Sub Main before running the journal.

Option Strict Off
Imports System
Imports System.Collections.Generic
Imports NXOpen
Imports NXOpen.UF

Module Module2

Dim theSession As Session = Session.GetSession()
Dim theUfSession As UFSession = UFSession.GetUFSession
Dim workPart As Part = theSession.Parts.Work

Sub Main()

'**************************************************
'* constants to find tabular note section and cell
'* change these as necessary before running journal
'*
'* note that computers start counting with zero
'* a tabular note with 3 columns and 5 rows
'* will have columns 0, 1, 2
'* and rows 0, 1, 2, 3, 4
'* counting starts at top left cell
'* this is accounted for later in the code
Const tableName As String = "TABLETEST"
Const rowNumber As Integer = 1
Const columnNumber As Integer = 1
Const newText As String = "testing"
'**************************************************

Dim myTableSection As Annotations.TableSection = Nothing
Dim myTableTag As Tag = Tag.Null

If IsNothing(theSession.Parts.Work) Then
'active part required
Return
End If

Dim lw As ListingWindow = theSession.ListingWindow
lw.Open()

Const undoMarkName As String = "NXJ journal"
Dim markId1 As Session.UndoMarkId
markId1 = theSession.SetUndoMark(Session.MarkVisibility.Visible, undoMarkName)

'lw.WriteLine("table sections: " & workPart.Annotations.TableSections.ToArray.Length.ToString)
For Each ts As Annotations.TableSection In workPart.Annotations.TableSections
'lw.WriteLine("name: " & ts.Name)
If ts.Name.ToUpper = tableName.ToUpper Then
myTableSection = ts
theUfSession.Tabnot.AskTabularNoteOfSection(ts.Tag, myTableTag)
End If
Next

If IsNothing(myTableSection) Then
lw.WriteLine("tabular note not found with name: " & tableName)
Return
End If

Dim numCols As Integer
theUfSession.Tabnot.AskNmColumns(myTableTag, numCols)
'lw.WriteLine(tableName & " columns: " & numCols.ToString)
If numCols < columnNumber Then
lw.WriteLine("error: tabular note '" & tableName & "' only has " & numCols.ToString & " columns")
lw.WriteLine(" columnNumber = " & columnNumber.ToString)
Return
End If

Dim numRows As Integer
theUfSession.Tabnot.AskNmRows(myTableTag, numRows)
'lw.WriteLine(tableName & " rows: " & numRows.ToString)
If numRows < rowNumber Then
lw.WriteLine("error: tabular note '" & tableName & "' only has " & numRows.ToString & " rows")
lw.WriteLine(" rowNumber = " & rowNumber.ToString)
Return
End If

Dim rowTag As Tag = Tag.Null
'use rowNumber - 1 so that the returned row matches the expected input
'row numbering starts at 0, not 1
theUfSession.Tabnot.AskNthRow(myTableTag, rowNumber - 1, rowTag)
If rowTag = Tag.Null Then
lw.WriteLine("error: row not found")
Return
End If

Dim colTag As Tag = Tag.Null
'use columnNumber - 1 so that the returned column matches the expected input
'column numbering starts at 0, not 1
theUfSession.Tabnot.AskNthColumn(myTableTag, columnNumber - 1, colTag)
If colTag = Tag.Null Then
lw.WriteLine("error: column not found")
Return
End If

Dim myCellTag As Tag = Tag.Null
theUfSession.Tabnot.AskCellAtRowCol(rowTag, colTag, myCellTag)
theUfSession.Tabnot.SetCellText(myCellTag, newText)

lw.Close()

End Sub

Public Function GetUnloadOption(ByVal dummy As String) As Integer

'Unloads the image immediately after execution within NX
GetUnloadOption = NXOpen.Session.LibraryUnloadOption.Immediately

End Function

End Module